Deser is a library for serializing and deserializing Nim data structures efficiently and generically. Just like Serde.

Explore

First, install Deser via nimble install deser.

Deser is not a parser library. You need to install some parser from Supported formats.

We use deser_json for example - nimble install deser_json.

Let's say we have an API with Message type that has this output:

const json = """
{
  "id": 1,
  "text": "Hello!",
  "created": 1660848266
}
"""

Let's try to map it to the Nim object. Use makeSerializable and makeDeserializable to generate serialize and deserialize procedures for your type.

import
  deser,
  deser_json

type
  Message = object
    id: int
    text: string
    created: int

makeSerializable(Message)
makeDeserializable(Message)

Use toJson and fromJson procedures from deser_json to serialize and deserialize to/from JSON:

let chat = Message.fromJson(json)
echo chat.toJson()

De/serialize Time and DateTime

In previous section we created Message type where created field is the time in unix format.

It is not convenient to work with it as int. But if we try to just use Time, we get an error:

Error: type mismatch: got <typedesc[Time], Deserializer>
but expected one of: ...

To fix this error, we need to use the serializeWith and deserializeWith pragmas.

Full code:

import std/times

import
  deser,
  deser_json

proc toTimestamp(self: Time, serializer: var auto) =
  serializer.serializeInt64(self.toUnix())

proc fromTimestamp(deserializer: var auto): Time =
  fromUnix(deserialize(int64, deserializer))

type
  Message = object
    id: int
    text: string
    created {.serializeWith(toTimestamp), deserializeWith(fromTimestamp).}: Time

makeSerializable(Message)
makeDeserializable(Message)

Example:

import std/times

import
  deser,
  deser_json

type
  Message = object
    id: int
    text: string
    created {.deserWith(UnixTimeFormat).}: Time

const json = """
{
  "id": 1,
  "text": "Hello!",
  "created": 1660848266
}
"""
let chat = Message.fromJson(json)
echo chat.toJson()

Supported std-types

• bool
• int8-64 (int serializaed as int64)
• uint8-64 (uint serialized as uint64)
• float32-64 (float serializaed as float64)
• char
• string
• seq
• array
• enum (serialized as the parser decides)
• tuple (serialized as array)
• set
• range
• Option
• HashSet
• OrderedSet
• Table
• OrderedTable

Supported formats

How to make bindings

• JSON - deser_json

Customize serialization process

Deser allows you to customize the serialization process, and the configuration will be applied to any parser.

Configuration is done with pragmas that are applied at compile-time. View available pragmas.

How to make bindings

Check example at deser_json.

Check helpers templates for serialization and deserialization.